|
PureBytes Links
Trading Reference Links
|
|
The above URL was the basis of an indicator that I
designed to
detect and display WolfeWaves. This was first posted
to this
list quite a while ago so many of you may have the
application.
The .ela and the source code (text) are
attached.
An .gif shows one application of this
indicator.
I hope that you will apply this indicator to many symbols
of many
time intervals and judge for yourself it's
suitability. Please
check the URL for further discussion.
I have not as yet attempted to construct a strategy out of
the
indicator but it would be easy since most of the line
drawing is
done with trendlines.
Clyde
- - - - - - - - - - - - - - - - - - - - - - - - - - - - Clyde
Lee
Chairman/CEO (Home of
SwingMachine) SYTECH
Corporation email: clydelee@xxxxxxxxxxxx 7910
Westglen, Suite 105
Office: (713) 783-9540 Houston, TX
77063
Fax: (713) 783-1092 Details
at:
www.theswingmachine.com- - - -
- - - - - - - - - - - - - - - - - - - - - - - -
----- Original Message -----
Sent: Sunday, October 10, 2004 8:31
AM
Subject: [RT] Wolfe Waves
Ever since reading Linda
Raschke's chapter on the Wolfe Waves, in her book Street Smarts, I have
been intrigued by this methodology.
I notice that Bill Wolfe sells
his teaching course on his concept for $3K, a somewhat pricey
amount. I was wondering if anyone here has taken the course and traded
this method, or can comment on it otherwise.
Thanks in advance for your
comments.
JohnO
| Yahoo! Groups Sponsor |
ADVERTISEMENT
![click here]() | |
![]() |
Yahoo! Groups Links
|
Attachment:
qqq-d_to2004.gif
Description: GIF image
{
Indicator: Wolfe_Waves_I
Purpose: Find 4 turning points which meet defined criteria and
draw the ETA lines and the EPA line.
Author: Clyde Lee, Copyrighted 2001
Limitations: This Tradestation indicator is furnished to the members
of the MedianLine/RealTraders list with the understanding
that they will use this indicator for personal use only
and will not distribute to others.
The following is from:
http://www.wolfewave.com/an_illustration_along_with_the_rules.htm
Rules for Bullish WolfeWave Structure
Please note the odd sequence in counting, as you will see, it is necessary
for the inductive analysis. By starting with a top we are assured of beginning
our count on a new wave. (The reverse would apply for a bearish wave.)
The 2 point is a top.
The 3 point is the bottom of the first decline.
The 1 point is the bottom prior to point 2 (top), that 3 has surpassed.
The 4 point is the top of the rally after point 3.
The 5 point is the bottom after point 4 and is likely to exceed the
extended trend line of 1 to 3.
This is the entry point for a ride to the EPA line (1 to 4).
Estimated Price at Arrival (EPA) is trend line of 1 to 4 at apex of
extended trend line of 1 to 3 and extended trend line of 2 to 4.
Estimated Time of Arrival (ETA) is apex of extended trend line
of 1 to 3 and 2 to 4.
/.EPA
. /
2 . /
/\ 4 . /
/ \ . /\ /
/ \ . / \ /
/ . \ / \ /
\/ \ / \ /
1 \/ \ /
3 \/
5
}
Inputs: NBars(13), {Number of bars for Swing_Lee pivot picking }
MaxBars(250); {Maximum number of bars forward to search for }
{Match/Crossing of ETA lines to set end EPA }
{If this is set to a very high number, the time}
{to compute and plot will become excessive. }
Vars: TPCount(0),Direct(0),
HoldPrice(0),BarsBk(0),
Slope1(0),Slope2(0),
ETA1(0),ETA2(0),EPA(0),
NewDate(0),NewTime(0);
Arrays: TPDate[4](0),TPTime[4](0),TPBar[4](0),TPPrice[4](0),TPDirect[4](0);
Direct=Swing_Lee_Simple(NBars,False);
If Sign(Direct)<>Sign(Direct[1]) then begin
BarsBk=AbsValue(Direct);
{Found a TurningPoing so increase count}
TPCount=TPCount+1;
{Save the proper price}
If Direct<0 then HoldPrice=High[BarsBk]
else HoldPrice=Low [BarsBk];
{Push the Stack}
For Value1=1 to 3 begin
TPDate[Value1] =TPDate[Value1+1];
TPTime[Value1] =TPTime[Value1+1];
TPBar[Value1] =TPBar[Value1+1];
TPPrice[Value1] =TPPrice[Value1+1];
TPDirect[Value1]=TPDirect[Value1+1];
End;
{Save Current Data}
TPDate[4] =Date[BarsBk];
TPTime[4] =Time[BarsBk];
TPBar[4] =CurrentBar-BarsBk;
TPPrice[4] =HoldPrice;
TPDirect[4]=Sign(Direct);
Plot1[BarsBk](HoldPrice,"TP");
If TPCount>3 then begin
{If we have 4 TP's then we can look for WW}
Condition1=False;Condition2=False;
Slope1=(TPPrice[3]-TPPrice[1])/(TPBar[1]-TPBar[3]);
Slope2=(TPPrice[4]-TPPrice[2])/(TPBar[2]-TPBar[4]);
If TPDirect[1]>0 then begin
{Look for Bullish WW}
Condition1=
TPPrice[4]>TPPrice[3] and
TPPrice[4]<TPPrice[2] and
TPPrice[3]<TPPrice[1] and
TPPrice[4]>TPPrice[1] and
Slope1 <Slope2 ;
End
Else Begin
{Look for Bearish WW}
Condition2=
TPPrice[4]<TPPrice[3] and
TPPrice[4]>TPPrice[2] and
TPPrice[3]>TPPrice[1] and
TPPrice[4]<TPPrice[1] and
Slope1 >Slope2 ;
End;
{Plot the wave and lines if it exists}
If Condition1 or Condition2 then begin
ETA1=TL_NEW(TPDate[1],TPTime[1],TPPrice[1],TPDate[3],TPTime[3],TPPrice[3]);
ETA2=TL_NEW(TPDate[2],TPTime[2],TPPrice[2],TPDate[4],TPTime[4],TPPrice[4]);
EPA =TL_NEW(TPDate[1],TPTime[1],TPPrice[1],TPDate[4],TPTime[4],TPPrice[4]);
Value5=TL_New(Date,Time,TL_GetValue(ETA1,Date,Time),
Date,Time,TL_GetValue(ETA2,Date,Time));
Value1=mod(tpcount,6)+2;
Value1=red;
TL_SetColor(ETA1,VALUE1);
TL_SetColor(ETA2,VALUE1);
TL_SetColor(EPA ,VALUE1);
TL_SetColor(Value5,Red);
TL_SetSize(Value5,3);
Value2=0;
Value1=0;
While Value2=0 and Value1< MaxBars begin
Value2=BarsToDate_Time(TPBar[4]-TPBar[3], Value1, NewDate, NewTime);
Value3=TL_GetValue(ETA2, NewDate, NewTime)-TL_GetValue(ETA1, NewDate, NewTime);
If Condition1 and Value3>0 then Value2=0;
If Condition2 and Value3<0 then Value2=0;
Value1=Value1+1;
End;
If Value2<>0 or Value1=MaxBars then begin
TL_SetEnd(ETA1, NewDate, NewTime, TL_GetValue(ETA1, NewDate, NewTime));
Value7=TL_GetValue(ETA2, NewDate, NewTime);
TL_SetEnd(ETA2, NewDate, NewTime, Value7);
Value8=Text_New(NewDate,NewTime,Value7,"ETA");
Text_SetStyle(Value8, 0, 2);
Value7=TL_GetValue(EPA , NewDate, NewTime);
TL_SetEnd(EPA , NewDate, NewTime, Value7);
Value8=Text_New(NewDate,NewTime,Value7,"EPA");
Text_SetStyle(Value8, 0, 2);
End;
End;
End;
End;
Attachment:
Description: Binary data
|
