Re: [EquisMetaStock Group] Re: Explorer

["Roy Larsen" <rlarsen@xxxxxxxxxx>]

Hi Mark


Without studying the indicator my only thoughts at present are that with to extract the most recent value with the default settings you'd need to use something like ValueWhen(1, Signal<>0,Signal).

{Col A}
Signal:=Fml("Up/DownSwing average Volume v3.0");
ValueWhen(1,Signal<>0,Signal);


Regards

Roy



  ----- Original Message ----- 
  From: markumansky 
  To: equismetastock@xxxxxxxxxxxxxxx 
  Sent: Sunday, July 08, 2007 1:50 AM
  Subject: [EquisMetaStock Group] Re: Explorer


  Thanks Roy,

  I am trying to create an Explorer from the following indicator. Can
  you help?

  {Up/DownSwing average Volume v3.0
  ©Copyright 2006 Jose Silva.
  For personal use only.
  http://www.metastocktools.com }

  { User inputs }
  choose:=Input("Avg Volume: [1]UpSwing, [2]DownSwing, [3]Both",1,3,3);
  ch:=Input("ZigZag minimum change %",.01,100,0.5);
  plot:=Input("Up/Down [1]Avg Vol [2]Swings, [3]ZigZag, [4]Pk/Tr",1,4,1);

  { ZigZag }
  zz:=Zig(C,ch,%);

  { Up/Down bar count }
  pkBars:=PeakBars(1,C,ch);
  trBars:=TroughBars(1,C,ch);

  { Peaks/Troughs }
  pk:=pkBars=0;
  tr:=trBars=0;

  { ---------- *** UpSwing Volume *** ---------- }

  { Up swings }
  UpSwing:=zz>Ref(zz,-1);

  { Up swing volume }
  UpSwingVol:=V*UpSwing;

  { Accumulate & reset UpVolume }
  acc:=Cum(UpSwingVol);
  accUpVol:=acc-ValueWhen(1,pkBars=0,acc);

  { Average UpSwing Volume }
  avgUpVol:=accUpVol/Max(trBars,.00001);

  { Restrict avg Volume to peak bar }
  avgUpVolPk:=Ref(avgUpVol,-1)*pk;

  { --------- *** DownSwing Volume *** --------- }

  { Down swings }
  DwSwing:=zz<Ref(zz,-1);

  { Down swing volume }
  DwSwingVol:=V*DwSwing;

  { Accumulate & reset DownVolume }
  acc:=Cum(DwSwingVol);
  accDwVol:=acc-ValueWhen(1,trBars=0,acc);

  { Average DownSwing Volume }
  avgDwVol:=accDwVol/Max(pkBars,.00001);

  { Restrict avg Volume to trough bar }
  avgDwVolTr:=Ref(avgDwVol,-1)*tr;

  { Choose Volume display }
  swingAvgVol:=
  If(choose=1,avgUpVol,
  If(choose=2,avgDwVol,
  avgUpVolPk-avgDwVolTr));

  { Plot in own window }
  If(plot=1,swingAvgVol,
  If(plot=2,UpSwing-DwSwing,
  If(plot=3,zz,pk-tr)))

  Thanks in advance for your assistance and comments!
  Mark

  --- In equismetastock@xxxxxxxxxxxxxxx, "Roy Larsen" <rlarsen@xxx> wrote:
  >
  > Hi Mark
  > 
  > 
  > If your indicator is able to be written to give weekly signals on
  EOD data (for example), then a single exploration could check the
  indicator value for any timeframe using just EOD data. Check out
  http://www.metastocktips.co.nz/other_formulas.html for some examples
  of indicators set up for one timeframe plotting on data for a shorter
  timeframe.
  > 
  > Another way to go would be to have three explorations set up to
  examine your indicator in its native form (no rewriting for other
  timeframes), and then set the three explorations to execute on the
  three different timeframes. The first exploration would scan the whole
  database, the second would use the results from the first, and the
  third would use the results from the second.
  > 
  > Regards
  > 
  > Roy
  > www.metastocktips.co.nz
  > 
  > 
  > ----- Original Message ----- 
  > From: markumansky 
  > To: equismetastock@xxxxxxxxxxxxxxx 
  > Sent: Sunday, July 01, 2007 5:36 PM
  > Subject: [EquisMetaStock Group] Explorer
  > 
  > 
  > Hi All,
  > 
  > Can anyone suggest a way to program the explorer to signal a contract
  > when an indicator has given the same signal on all time-frames
  > (monthly/weekly/daily)?
  > 
  > Thanks in advance.
  > Mark
  > 
  > 
  > 
  > 
  > 
  > __________ NOD32 2366 (20070701) Information __________
  > 
  > This message was checked by NOD32 antivirus system.
  > http://www.eset.com
  > 
  > 
  > [Non-text portions of this message have been removed]
  >



   

  __________ NOD32 2383 (20070706) Information __________

  This message was checked by NOD32 antivirus system.
  http://www.eset.com


[Non-text portions of this message have been removed]



 
Yahoo! Groups Links

<*> To visit your group on the web, go to:
    http://groups.yahoo.com/group/equismetastock/

<*> Your email settings:
    Individual Email | Traditional

<*> To change settings online go to:
    http://groups.yahoo.com/group/equismetastock/join
    (Yahoo! ID required)

<*> To change settings via email:
    mailto:equismetastock-digest@xxxxxxxxxxxxxxx 
    mailto:equismetastock-fullfeatured@xxxxxxxxxxxxxxx

<*> To unsubscribe from this group, send an email to:
    equismetastock-unsubscribe@xxxxxxxxxxxxxxx

<*> Your use of Yahoo! Groups is subject to:
    http://docs.yahoo.com/info/terms/