|
PureBytes Links
Trading Reference Links
|
c_cruizer
Have you set your exploration to weekly periodicity? That seems to me to be the simplest
solution. If you must run a daily exploration then you could set up the code below to match your
weekly chart values, Stoch(5,3) and Mov(Stoch(5,3),3,S) , and test weekly values using daily
perodicity.
The difference between daily and weekly periodicy is not as simple as multiplying the number of
periods by 5.
Set up my indicator after installing the required "Calendar Week counter" (you can get that from
Jose's site at
http://users.bigpond.com/prominex/pegasus.htm) . Once you have both indicators installed you can
plot the Weekly Stoch indicator on either weekly or daily charts - that makes it easy to check that
the values are correct.
Good luck with it anyway
{Weekly Stochastic Osc SMA}
{2004 Roy Larsen, rlarsen@xxxxxxxxxxxxxx}
{for use on daily charts with
Jose Silva's "Calendar Week counter"}
K:=Input("Weekly Stochastic Oscillator %K Periods",1,99,5);
N:=Input("%K Slowing Periods" ,1,99,3);
R:=Input("%D SMA Periods",1,99,3);
F:=Input("End of Week, 5=Friday 6=Saturday 7=Sunday",5,7,5);
Q:=Input("Display Mode, 0=Static 1=Dynamic 2=Test",0,2,2);
{0=Display, update on Friday when possible}
{1=Display, update on each new bar}
{2=Backtest, update on first bar of new week}
G:=LastValue(Highest(Sum(DayOfWeek()=F,5))=5);
I:=Fml("Calendar Week counter");
I:=Abs(I-ValueWhen(2-G,1,I)); M:=G OR I>0;
F:=G OR (DayOfWeek()=F AND I=0);
A:=LastValue(Cum(1)-1)=Cum(1);
B:=ValueWhen(2,1,A);
J:=If(F,1,If(Alert(F,2)=0 AND M,2,0));
J:=If(A+LastValue(J)>2 OR B+(Q=1)=2,1,J);
J:=If(G,1,If(Q=2 OR Cum(J)<=1,M*2,J));
Hw:=HighestSince(1,M,H);
Hw:=ValueWhen(1,J,If(J=1,Hw,ValueWhen(2,1,Hw)));
Lw:=LowestSince(1,M,L);
Lw:=ValueWhen(1,J,If(J=1,Lw,ValueWhen(2,1,Lw)));
Cw:=ValueWhen(1,J,If(J=1,C,ValueWhen(2,1,C)));
Hw:=ValueWhen(1,Hw>0,Hw);
Lw:=ValueWhen(1,Lw>0,Lw);
Cw:=ValueWhen(1,Cw>0,Cw);
Z:=Cum((Cw-LowestSince(K,J,Lw))*(J>0));
Z:=Z-ValueWhen(N+1,J,Z);
I:=Cum((HighestSince(K,J,Hw)- LowestSince(K,J,Lw))*(J>0));
I:=I-ValueWhen(N+1,J,I);
I:=ValueWhen(1,Cum(I>0)>0,I);
X:=100*Z/I; X:=ValueWhen(1,Cum(J>0)>=K+N,X);
Y:=Cum((J>0)*X); Y:=(Y-ValueWhen(R+1,J,Y))/R;
Y:=ValueWhen(1,Cum(J>0)>=K+N+R,Y);
X; {%K}
Y; {%D}
Kind regards
Roy Larsen
www.metastocktips.co.nz
Free formulas and MS links
----- Original Message -----
From: "c_cruizer" <no_reply@xxxxxxxxxxxxxxx>
To: <equismetastock@xxxxxxxxxxxxxxx>
Sent: Monday, December 06, 2004 12:20 PM
Subject: [EquisMetaStock Group] Weekly chart with STO
>
>
> I have a set of charts that have the periodicity set to weekly. I'm
> trying to create an explorer that tests to see if the STO is less
> than 25 and the STO is less than the STO MA.
>
> I've tried the following:
> Stoch(25,15) < 25 AND
> (Mov(Stoch(25 ,15 ), 15, S) > Stoch(25,15))
>
> Neigher the first line nor the second line work correctly all the
> time. How should I be building a test for a weekly chart?
>
> Thanks
>
>
>
>
>
>
>
> Yahoo! Groups Links
>
>
>
>
>
>
>
>
>
------------------------ Yahoo! Groups Sponsor --------------------~-->
$4.98 domain names from Yahoo!. Register anything.
http://us.click.yahoo.com/Q7_YsB/neXJAA/yQLSAA/BefplB/TM
--------------------------------------------------------------------~->
Yahoo! Groups Links
<*> To visit your group on the web, go to:
http://groups.yahoo.com/group/equismetastock/
<*> To unsubscribe from this group, send an email to:
equismetastock-unsubscribe@xxxxxxxxxxxxxxx
<*> Your use of Yahoo! Groups is subject to:
http://docs.yahoo.com/info/terms/
|