Re: [Metastockusers] RSI formula?

["Roy Larsen" <rlarsen@xxxxxxxxxxxxxx>]

Ruud

> For some reason (will post later in this group) i need the RSI as a
> formula. I like to have the RSI like MetaStock calculates it. Has
> anyone here done that before?
>
> Why i need this.
> I'm using a very short RSI oscilator with an 2 days MA trigger line.
> I like to try to calculate on which level this oscilator will cross
> that line. When i succeed with this indicator i'll post it here.
>
> Kind regards
> Ruud

Here's my total collection of RSI formulas. The first three are essentially the same but written
slightly differently to show a different aspect of the calculation. The RSI Price Lookahead is not
my creation but you may find it useful for your project. Well, just maybe.

Roy

  {RSI Indicator}
A:=Input("Periods",2,99,10);
B:=P; {target array}
U:=Wilders(If(B>Ref(B,-1),B-Ref(B,-1),0),A);
D:=Wilders(If(B<Ref(B,-1),Ref(B,-1)-B,0),A);
100-(100/(1+(U/D)));

  {RSI Indicator}
A:=Input("RSI periods",2,99,10);
R:=1/A;
X:=If(C>Ref(C,-1),C-Ref(C,-1),0);
Y:=If(C<Ref(C,-1),Ref(C,-1)-C,0);
U:=PREV*(1-R)+X*R;
D:=PREV*(1-R)+Y*R;
100-(100/(1+(U/D)));

  {RSI Indicator}
A:=Input("Periods",2,99,10);
U:=Wilders(If(C>Ref(C,-1),C-Ref(C,-1),0),A);
D:=Wilders(If(C<Ref(C,-1),Ref(C,-1)-C,0),A);
100-(100/(1+(U/D)));

  {RSI Price Lookahead}
R:=Input("RSI Threshold",1,100,50);
D:=Input("RSI Periods  ",1,100,10);
K:=Ref(C,-1);
Up:=Wilders(If(C>K,C-K,0),D);
Dn:=Wilders(If(K>C,K-C,0),D);
X:=(D-1)*(Dn*R/(100-R)-Up);
If(X>=0,C+X,C+X*(100-R)/R);



To unsubscribe from this group, send an email to:
Metastockusers-unsubscribe@xxxxxxxxxxx

 

Yahoo! Groups Links

To visit your group on the web, go to:
 http://groups.yahoo.com/group/Metastockusers/

To unsubscribe from this group, send an email to:
 Metastockusers-unsubscribe@xxxxxxxxxxxxxxx

Your use of Yahoo! Groups is subject to:
 http://docs.yahoo.com/info/terms/