[EquisMetaStock Group] Re: 'BETWEEN' & 'AND"

["Jose Silva" <josesilva22@xxxxxxxxx>]

Jeevan, try this Exploration/Indicator code:


Column A: Count
===============
---8<-------------------------------------

{ Count of RSI>85 events
   for period 11/01/05 to 11/30/06.
  http://www.metastocktools.com }

{ Event to count }
event:=RSI(14)>85;

{ Date period inputs }
StDay:=01;    { Start Day [1~31]}
StMnth:=11;   { Start Month [1~12]}
StYear:=2005; { Start Year [1800~2200]}
EnDay:=30;    { End Day [1~31]}
EnMnth:=11;   { End Month [1~12]}
EnYear:=2006; { End Year [1800~2200]}

{ Selected date period }
start:=Year()>StYear
 OR (Year()=StYear AND (Month()>StMnth
 OR Month()=StMnth AND DayOfMonth()>=StDay));
end:=Year()<EnYear
 OR (Year()=EnYear AND (Month()<EnMnth
 OR Month()=EnMnth AND DayOfMonth()<=EnDay));
date:=start
  AND (end OR (start AND Alert(start=0,2)));

{ Event count within period }
Cum(event*date)

---8<-------------------------------------


Filter
======
ColA>0


jose '-)
http://www.metastocktools.com




--- In equismetastock@xxxxxxxxxxxxxxx, "Jeevan" <jeevan@xxx> wrote:
>
> 
> Hi all,
> 
> 
> I would like to create an exploration by which I will get to know, 
> during the previous year, how may occasions the RSI of a set of
> different securities had gone above 85?
> 
> 
> How should I define the period  between 11/01/05 and 11/30/06 ?
> 
> 
> Please help me.
> 
> 
> Thanks in advance
> 
> 
> Jeevan




 
Yahoo! Groups Links

<*> To visit your group on the web, go to:
    http://groups.yahoo.com/group/equismetastock/

<*> Your email settings:
    Individual Email | Traditional

<*> To change settings online go to:
    http://groups.yahoo.com/group/equismetastock/join
    (Yahoo! ID required)

<*> To change settings via email:
    mailto:equismetastock-digest@xxxxxxxxxxxxxxx 
    mailto:equismetastock-fullfeatured@xxxxxxxxxxxxxxx

<*> To unsubscribe from this group, send an email to:
    equismetastock-unsubscribe@xxxxxxxxxxxxxxx

<*> Your use of Yahoo! Groups is subject to:
    http://docs.yahoo.com/info/terms/