[EquisMetaStock Group] Re: How to plot the last values of Jackson Zones

[pumrysh <no_reply@xxxxxxxxxxxxxxx>]

Metabully,

Several things to be aware of.

There was a discussion by Henry1224 on the Equis forum. Those links are 
below. Also Henry offered a lastvalue version which you should look 
into.

http://forum.equis.com/forums/post/7188.aspx
http://forum.equis.com/forums/thread/1255.aspx

I can offer an alternative but if the original code isn't correct it 
will not solve the problem. My solution simply restricts the output to 
a selected display period and could be used with any indicator.

The original codes are listed as well so that you can see what I did. 
The final formula is the one you want.

Hope this helps,


Preston



{Jackson Zones}
TF:=Input("1=hour 2=day 3=week 4=month 5=year ",1,5,4);
NW:=If(TF=1,ROC(Minute(),1,$)<0,
If(TF=2,ROC(Hour(),1,$)<0,
If(TF=3,ROC(DayOfWeek(),1,$)<0,
If(TF=4,ROC(DayOfMonth(),1,$)<0,ROC(Month(),1,$)<0))));
WH:=ValueWhen(1,Nw,Ref(HighestSince(1,Nw,H),-1));
WL:=ValueWhen(1,Nw,Ref(LowestSince(1,Nw,L),-1));
WCL:=ValueWhen(1,Nw,Ref(C,-1));
BP:=(WH+WL+WCL)/3;
D:=((WH-WL)/2)+BP;
B:=BP-((WH-WL)/2);
D1:=(WH-WL)+BP;
B1:=BP-(WH-WL);
SB1:=BP-((WH-WL)*.618);
SB2:=BP-((WH-WL)*1.382);
RB1:=((WH-WL)*.618)+BP;
RB2:=((WH-WL)*1.382)+BP;
RB2;D1;RB1;D;BP;B;SB1;B1;SB2;
{end}




{Restricted Display v2.0} 
{Written by Preston Umrysh} 
{Correctly Displays an indicator for a specified period of time}
Pds:=Input("Indicator periods ",1,1111,10); 
DisPds:=Input("Select Display Periods",1,1111,10); 
BackPds:=Input("Select Setback Periods",0,1111,0); 

{ Indicator } 
Ind:=Mov(C,pds,S); 
 
{ Restricted Display } 
ResPds:= Alert(BarsSince(Cum(1)=LastValue(Cum(1)-(DisPds+BackPds))
=1),1); 
Plot:=ValueWhen(1,ResPds,Ref(Ref(Ind,-BackPds),BackPds));
Plot; 
{end}





{Jackson Zones Restricted} 
TF:=Input("1=hour 2=day 3=week 4=month 5=year ",1,5,4);
NW:=If(TF=1,ROC(Minute(),1,$)<0,
If(TF=2,ROC(Hour(),1,$)<0,
If(TF=3,ROC(DayOfWeek(),1,$)<0,
If(TF=4,ROC(DayOfMonth(),1,$)<0,ROC(Month(),1,$)<0))));
WH:=ValueWhen(1,Nw,Ref(HighestSince(1,Nw,H),-1));
WL:=ValueWhen(1,Nw,Ref(LowestSince(1,Nw,L),-1));
WCL:=ValueWhen(1,Nw,Ref(C,-1));
BP:=(WH+WL+WCL)/3;
D:=((WH-WL)/2)+BP;
B:=BP-((WH-WL)/2);
D1:=(WH-WL)+BP;
B1:=BP-(WH-WL);
SB1:=BP-((WH-WL)*.618);
SB2:=BP-((WH-WL)*1.382);
RB1:=((WH-WL)*.618)+BP;
RB2:=((WH-WL)*1.382)+BP;
{Restricted Display v2.0} 
{Written by Preston Umrysh} 
{Correctly Displays an indicator for a specified period of time}

DisPds:=Input("Select Display Periods",1,1111,10); 
BackPds:=Input("Select Setback Periods",0,1111,0); 
 
{ Restricted Display } 
ResPds:= Alert(BarsSince(Cum(1)=LastValue(Cum(1)-(DisPds+BackPds))
=1),1); 
ValueWhen(1,ResPds,Ref(Ref(RB2,-BackPds),BackPds));
ValueWhen(1,ResPds,Ref(Ref(D1,-BackPds),BackPds));
ValueWhen(1,ResPds,Ref(Ref(RB1,-BackPds),BackPds));
ValueWhen(1,ResPds,Ref(Ref(D,-BackPds),BackPds));
ValueWhen(1,ResPds,Ref(Ref(BP,-BackPds),BackPds));
ValueWhen(1,ResPds,Ref(Ref(B,-BackPds),BackPds));
ValueWhen(1,ResPds,Ref(Ref(SB1,-BackPds),BackPds));
ValueWhen(1,ResPds,Ref(Ref(B1,-BackPds),BackPds));
ValueWhen(1,ResPds,Ref(Ref(SB2,-BackPds),BackPds));
{end}


 

--- In equismetastock@xxxxxxxxxxxxxxx, metabully <no_reply@xxx> wrote:
>
> The original Jackson Zones code could be found in Trader online 
website
> 
> I am wondering could anyone adapt and revise the code to show the 
last 
> values of Jackson Zones only
> 
> 
> Best rgds
>



------------------------------------

Yahoo! Groups Links

<*> To visit your group on the web, go to:
    http://groups.yahoo.com/group/equismetastock/

<*> Your email settings:
    Individual Email | Traditional

<*> To change settings online go to:
    http://groups.yahoo.com/group/equismetastock/join
    (Yahoo! ID required)

<*> To change settings via email:
    mailto:equismetastock-digest@xxxxxxxxxxxxxxx 
    mailto:equismetastock-fullfeatured@xxxxxxxxxxxxxxx

<*> To unsubscribe from this group, send an email to:
    equismetastock-unsubscribe@xxxxxxxxxxxxxxx

<*> Your use of Yahoo! Groups is subject to:
    http://docs.yahoo.com/info/terms/